Title: This is Mplus syntax for Linear Model 2:
       bifactor model with one group factor;

Data: file is demodata.txt;
Variable:
 Names are x1-x7 ;
 Usevariables are x1-x7;

MODEL:	

 attitude by x1* (a1) 
             x2-x7 (a2-a7);
 PAM by x1* (b1)
        x2-x3 (b2-b3);
 attitude@1;PAM@1;
 attitude with PAM@0;

 true by;
 true@0;
 true on attitude(g1)
         PAM(g2);
 x1-x7 (ve1-ve7);

model constraint:
 new(true error relia);
 g1=a1+a2+a3+a4+a5+a6+a7;
 g2=b1+b2+b3;
 true=g1*g1+g2*g2;
 error=ve1+ve2+ve3+ve4+ve5+ve6+ve7;
 relia=true/(true+error);





Title: This is Mplus syntax for Linear Model 3:
       bifactor model with two group factors;
Data: file is demodata.txt;
Variable:
 Names are x1-x7 ;
 Usevariables are x1-x7;

Model:

 attitude by x1* (a1)
             x2-x7 (a2-a7);
 PAM by x1* (b1)
        x2-x3 (b2-b3);
 negative by x2* (c1)
             x5-x6 (c2-c3);
 attitude@1;PAM@1;negative@1;
 attitude with PAM@0;
 attitude with negative@0;
 PAM with negative@0;

 true by;
 true@0;
 true on attitude(g1)
         PAM(g2)
         negative(g3);
 x1-x7 (ve1-ve7);

model constraint:
 new(true error relia);
 g1=a1+a2+a3+a4+a5+a6+a7;
 g2=b1+b2+b3;
 g3=c1+c2+c3;
 true=g1*g1+g2*g2+g3*g3;
 error=ve1+ve2+ve3+ve4+ve5+ve6+ve7;
 relia=true/(true+error);





Title: This is Mplus syntax for Linear Model 4: 
       bifactor model with one group factor and correlated errors;

Data: file is demodata.txt;
Variable:
 Names are x1-x7 ;
 Usevariables are x1-x7;

Model:
 attitude by x1* (a1)
             x2-x7 (a2-a7);
 PAM by x1* (b1)
        x2-x3 (b2-b3);

 attitude@1;PAM@1;
 attitude with PAM@0;

 x2 with x5(cov1);
 x2 with x6(cov2);
 x5 with x6(cov3);

 true by;
 true@0;
 true on attitude(g1)
         PAM(g2);
 x1-x7 (ve1-ve7);

 model constraint:
 new(true error relia);
 g1=a1+a2+a3+a4+a5+a6+a7;
 g2=b1+b2+b3;
 true=g1*g1+g2*g2;
 error=ve1+ve2+ve3+ve4+ve5+ve6+ve7+2*cov1+2*cov2+2*cov3;
 relia=true/(true+error);






Title: This is Mplus syntax for Non-Linear Model 2: bi-factor model with 1 group factor;

 Data: file is demodata.txt;
 Variable:
  Names are x1-x7 ;
  Usevariables are x1-x7;
  Categorical are x1-x7;

 Analysis:
  estimator=wlsmv;

 MODEL:
  attitude by x1* x2-x7;
  attitude@1;

  PAM by x1* x2-x3;
  PAM@1;
  attitude with PAM@0;

 Output: sampstat modindices;
!To compute nonlinear reliability based on this model
!the estimated polychoric correlation, loadings, and thresholds
!are imported into the SAS program provided in Green&Yang(2010b)